Pour écrire une formule de mise en forme conditionnelle, cliquez avec le bouton droit de la souris sur la zone ou le champ du rapport que la formule affectera, puis cliquez sur Formules de condition. Sélectionnez la condition voulue et saisissez la formule de condition dans la page Formules. Par exemple, vous pouvez mettre en forme le champ {Clients.VENTES DE L'ANNEE DERNIERE} de manière à imprimer les ventes de plus de 100 000 € en vert, celles de moins de 15 000 € en rouge et tout le reste en noir.
Exemple
//Conditional formatting example 1
If {Customer.Last Year's Sales} > 100000 Then
crGreen
Else If {Customer.Last Year's Sales} < 15000 Then
crRed
Else
crBlack
Dans la mesure où il s'agit d'une fonction de mise en forme de la couleur de police, la liste des constantes de couleur s'affiche sous la forme d'une liste commentée dans la page Formules. L'exemple précédent en utilise trois : crGreen, crRed and crBlack. Au lieu de cela, vous pourriez avoir utilisé les valeurs numériques réelles des constantes de couleur. Par exemple, la valeur de crRed est 255 et celle de crGreen est 32 768. Toutefois, la formule est plus lisible lorsque les constantes de couleur sont utilisées. Toutes les fonctions de constantes en syntaxe Crystal peuvent porter le préfixe "cr".
La syntaxe Crystal prend toujours en charge les fonctions constantes des versions précédentes qui n'ont pas le préfixe "cr". Vous pouvez, par exemple, utiliser "Red" au lieu de "crRed". Toutefois, l'utilisation du préfixe "cr" permet d'organiser les fonctions constantes et est recommandée.
Remarque : Certains attributs de mise en forme n'utilisent pas les fonctions constantes. Par exemple, si vous voulez ne pas imprimer les valeurs de {Clients.VENTES DE L'ANNEE DERNIERE} en cas de ventes inférieures à 50 000 €, vous pouvez écrire la formule de mise en forme conditionnelle suivante pour l'attribut de suppression :
//Conditional formatting example 2
If {Customer.Last Year's Sales} < 50000 Then
True //suppress the value
Else
False //do not suppress the value
Ou plus simplement :
//Conditional formatting example 3 -
//equivalent to example 2
{Customer.Last Year's Sales} < 50000
Si le montant des ventes de l'année dernière est inférieur à 50 000 €, l'expression
{Customer.Last Year's Sales} < 50000
est vraie, et la formule renvoie la valeur True. D'un autre côté, si le montant des ventes de l'année dernière est supérieur ou égal à 50 000 €, l'expression
{Customer.Last Year's Sales} < 50000
est fausse et la formule renvoie la valeur False.